#!ipxe

cpuid --ext 29 && set CPU-ARCH amd64 || set CPU-ARCH i386

:start
set def 10-RELEASE
menu Welcome to iPXE's mfsBSD Boot Menu (contact: kczekirda@freebsd.org)
item
item --gap -- ----------------------- mfsBSD releases ---------------------------------
item 11-CURRENT						11-CURRENT
item 10.0-RELEASE					10.0-RELEASE
item 9.3-RELEASE					9.3-RELEASE
item 8.4-RELEASE					8.4-RELEASE
item --gap -- -------------------------------------------------------------------------
item shell                          Enter iPXE shell
item reboot                         Reboot
item exit                           Exit (boot local disk)
item --gap -- -------------------------------------------------------------------------

choose --timeout 5000 --default ${def} sel || exit

iseq ${sel} shell && goto shell ||
iseq ${sel} reboot && goto reboot ||
iseq ${sel} exit && goto exit ||
goto ${sel}

:8.4-RELEASE
set rel 8.4-RELEASE
set ver 8
goto setiso

:9.3-RELEASE
set rel 9.3-RELEASE
set ver 9
goto versions

:10.0-RELEASE
set rel 10.0-RELEASE
set ver 10
goto versions

:11-CURRENT
set rel 11-CURRENT
set ver 11
goto versions

:versions
set def default
menu Welcome to iPXE's mfsBSD Boot Menu (contact: kczekirda@freebsd.org)
item
item --gap -- -------------------- mfsBSD versions ----------------------------
item default		default
item fai			Fully Automatic Installer
item --gap -- -------------------------------------------------------------------------
choose --timeout 5000 --default ${def} sel

iseq ${sel} fai && set rel ${rel}-fai ||

:setiso
set iso /files/iso/${ver}/${CPU-ARCH}/mfsbsd-${rel}-${CPU-ARCH}.iso
goto boot

:boot
kernel http://czyki.no-ip.info/memdisk iso raw
initrd ${iso}
boot

:shell
echo Type exit to get the back to the menu
shell
set menu-timeout 0
goto start

:reboot
reboot

:exit
sanboot --no-describe --drive 0x80